Рейтинг - 5.0 (5)

Всем привет! Этот урок я полностью посвятил чекпоинтам и маркерам.

Сами маркеры можно образно разделить на две большие группы: статические и плавающие. Статические маркеры - это объекты, которые прикреплены на карте, то есть не могут перемещаться. Плавающие - на оборот: свободно двигаются за игровыми субъектами. Как правило создаются они опкодами с описанием "AboveTo"( над чем-то ). Статичные же имеют разделение примерно на три ветви: чекпоинты, радарные и входные. Входные маркеры являют собою желтую "стрелку", идентичную плавающим маркерам, только не перемещается. Как правило их ставят при входе в какой-то интерьер.

Радарные маркеры являют собою сферу в игре с иконкой на карте. Такие маркеры обычно используют для обозначения важных мест, таких как закусочных, миссий и т.п.

Чекпоинты - это маркеры пути, то есть указатели места, куда нужно добраться. Они делятся также на два вида - обычные и гоночные. Последний вид используется, как правило, в гоночных миссиях. Они имеют точку позиции и точку, куда будет смотреть маркер.

Чтобы лучше понять эту классификацию я нарисовал картинку:

Существует несколько вариантов отображения плавающих маркеров на радаре. Для этого используется опкод:

018B: set_marker 0@ radar_mode 2
Здесь:
0@ - хэндл маркера
2 - режим отображения. Режимы указаны в таблице ниже
РежимОписание
0На радаре показывается маркер и стрелка ( он же по-умолчанию )
1Есть стрелка над субъектом, но на радаре ничего не показано
2На радаре ничего не показано и нет стрелки

Так же мы можем указать тип чекпоинта:

08FB: set_checkpoint 1@ type_to 0
Здесь:
0@ - хэндл чекпоинта
0 - тип чекпоинта. Типы указаны в таблице ниже
ТипОписание
0Желтый квадратик
1Синий квадратик
2Красный квадратик

Гоночные чекпоинты имеют свою особенность. Дело в том, что их можно перемещать. Если обычные прикреплены к месту, то другое дело с ГЧ ( они же гоночные чекпоинты ). К тому же мы можем задать размер. Создаются ГЧ следующим образом:

06D5: 0@ = create_racing_checkpoint_at -2699.3767 95.7964 4.3359 point_to -2699.5322 74.057 4.3359 type 0 radius 4.0
Здесь:
0@ - хэндл чекпоинта
-2699.3767 95.7964 4.3359 - место, где должна разместится контрольная точка
-2699.5322 74.057 4.3359 - координаты, куда будет смотреть ГЧ
0 - тип ГЧ
4.0 - размер гоночного чекпоинта

Отключается гоночные чекпоинты следующим опкодом:

06D6: disable_racing_checkpoint 0@

Переместить ГЧ можно следующим образом:

07F3: move_racing_checkpoint 0@ to -2710.7253 74.4686 4.1797
Здесь:
0@ - хэндл чекпоинта
-2710.7253 74.4686 4.1797 - новая позиция гоночного чекпоинта.

Можно ещё задать угол разворота ГЧ:

0996: set_racing_checkpoint 0@ Z_angle_to 179.2693

Давайте напишем небольшую миссию, где игроку нужно на "кукурузнике" облетать часть города Лос Сантос:

{$CLEO .cm}

//------------- Mission ---------------

:MISSION
thread 'MISSION'
gosub @MISSION_29_57 
if 
wasted_or_busted 
jf @MISSION_29_46 
gosub @MISSION_29_144 

:MISSION_29_46
$ONMISSION = 0 
mission_cleanup 
end_thread 

:MISSION_29_57
increment_mission_attempts 
$ONMISSION = 1 
00C0: set_current_time 4 0
03DE: set_pedestrians_density_multiplier_to 0.0
01EB: set_traffic_density_multiplier_to 0.0
0395: clear_area 0 at 2244.7144 -1851.5718 -0.1345 radius 300.0
Model.Load(#CROPDUST)
038B: load_requested_models
0@ = Car.Create(#CROPDUST, 2244.7144, -1851.5718, -0.1345)
Car.Angle(0@) = 269.8951
Model.Destroy(#CROPDUST)
072A: put_actor $PLAYER_ACTOR into_car 0@ driverseat
wait 2000
Camera.Restore_WithJumpCut
fade 1 1000
wait 1000
0ACF: show_formatted_styled_text "3" time 1000 style 4
097A: at 0.0 0.0 0.0 play_sound 1056
wait 1000
0ACF: show_formatted_styled_text "2" time 1000 style 4 
097A: at 0.0 0.0 0.0 play_sound 1056
wait 1000
0ACF: show_formatted_styled_text "1" time 1000 style 4 
097A: at 0.0 0.0 0.0 play_sound 1056
wait 1000
0ACF: show_formatted_styled_text "G0!" time 1000 style 4
097A: at 0.0 0.0 0.0 play_sound 1057
Player.CanMove(0) = true
Actor.SetImmunities($PLAYER_ACTOR, 0, 0, 0, 0, 0)
Car.SetImmunities(0@, 1, 1, 1, 1, 1)
0423: set_car 0@ improved_handling_to 2.0 // (float)
1@ = 0 // Index Point
9@ = 4 // Type Race Chackpoint

:MISSION_C
wait 0
06D6: disable_racing_checkpoint 8@
marker.Disable(10@)
if
1@ == 0
then
2@ = 2413.0439 
3@ = -1841.1782
5@ = 2413.2087
6@ = -2048.9414
end
if
1@ == 1
then
2@ = 2413.2087 
3@ = -2048.9414 
5@ = 2394.0317 
6@ = -2267.0752 
end
if
1@ == 2
then
2@ = 2394.0317 
3@ = -2267.0752 
5@ = 2225.1492 
6@ = -2451.5432 
end
if
1@ == 3
then
2@ = 2225.1492 
3@ = -2451.5432 
5@ = 2221.7722 
6@ = -2627.5698 
end
if
1@ == 4
then
2@ = 2221.7722 
3@ = -2627.5698 
5@ = 2380.2559 
6@ = -2664.9453 
end
if
1@ == 5
then
2@ = 2380.2559 
3@ = -2664.9453 
5@ = 2407.147 
6@ = -2510.7278 
end
if
1@ == 6
then
2@ = 2407.147 
3@ = -2510.7278 
5@ = 2489.533 
6@ = -2308.1719 
end
if
1@ == 7
then
2@ = 2489.533 
3@ = -2308.1719 
5@ = 2579.6653 
6@ = -2235.9314 
end
if
1@ == 8
then
2@ = 2579.6653 
3@ = -2235.9314 
5@ = 2582.5527 
6@ = -2116.0264 
end
if
1@ == 9
then
2@ = 2582.5527 
3@ = -2116.0264 
5@ = 2583.7729 
6@ = -2082.8301 
9@ = 1 // Finish!
end
if
1@ == 10
then
jump @MISSION_A
end
06D5: 8@ = create_racing_checkpoint_at 2@ 3@ 100.0 point_to 5@ 6@ 100.0 type 9@ radius 4.0
018A: 10@ = create_checkpoint_at 2@ 3@ 50.0

:MISSION_B
wait 0
if OR
Car.Wrecked(0@)
02BF: car 0@ sunk
then
jump @MISSION_29_144_END_CAR
end
if
not actor.InCar($PLAYER_ACTOR, 0@)
then
jump @MISSION_29_144_PLAYER_NOT_CAR
end
if
00EC: actor $PLAYER_ACTOR sphere 0 near_point 2@ 3@ radius 4.5 4.5
then
1@ += 1
097A: at 0.0 0.0 0.0 play_sound 1056
jump @MISSION_C
end
jump @MISSION_B

:MISSION_A
wait 2000
gosub @MISSION_END
Player.Money(0) += 10000
0394: play_music 1
01E3: show_text_1number_styled GXT 'M_PASS' number 10000 time 5000 style 1 // MISSION PASSED + MONEY
return 

:MISSION_29_144
wait 0 
gosub @MISSION_END
00BA: show_text_styled GXT 'M_FAIL' time 5000 style 1 // MISSION FAILED
return

:MISSION_29_144_END_CAR
wait 0 
gosub @MISSION_END
0AD0: show_formatted_text_lowpriority "Џpa®cЈop¦ y®њ¤¦o›e®!" time 5000 // Car Wrecked!
00BA: show_text_styled GXT 'M_FAIL' time 5000 style 1 // MISSION FAILED
return

:MISSION_29_144_PLAYER_NOT_CAR
wait 0 
gosub @MISSION_END
0AD0: show_formatted_text_lowpriority "‹Ё Јokњ®yћњ ¦pa®cЈop¦!" time 5000 // You not in car!
00BA: show_text_styled GXT 'M_FAIL' time 5000 style 1 // MISSION FAILED
return

:MISSION_END
wait 0
03DE: set_pedestrians_density_multiplier_to 1.0
01EB: set_traffic_density_multiplier_to 1.0
06D6: disable_racing_checkpoint 8@
marker.Disable(10@)
return

А также стартер к нему:

{$CLEO}
0000:

while 8AB0: not key_pressed 9 // Tab
wait 0
end

fade 0 1000
0ACF: show_formatted_styled_text "Fly in City" time 4000 style 2
Player.CanMove(0) = false
Actor.SetImmunities($PLAYER_ACTOR, 1, 1, 1, 1, 1)
wait 1000
0A94: start_custom_mission "Miss"
0A93: end_custom_thread

Результат:

Таким образом сюда ещё можно добавить таймер, что бы игрок живее летел к точке :) На этом урок окончен. Спасибо всем за время, которое вы уделили этой статье!


Теги: гоночный чекпоинт, маркер, Marker, чекпоинт, racing checkpoint, Checkpoint

Yurko_UA   (25.07.13 01:24)
А що за баг з датою?

wmysterio   (25.07.13 01:57)
Якщо ти про то, що додано 21-го числа, то це не баг. Я просто почав писати урок 21-го а закінчив оце сьогодні

blackful   (26.07.13 11:55)
отличный урок! автору респект! молодец!  smile

blackful   (26.07.13 12:15)
да,и почему у меня ошибку пишет :
"Неверный символ в идентификаторе MISSION_29_57  ." у меня последняя версия SB,и клео 4

wmysterio   (26.07.13 16:13)
Вы сами ответили на свой вопрос. Уберите лишние символы возле метки MISSION_29_57.

Nikkei   (29.05.14 01:10)
мало пояснения) особенно в первом коде самом большом

wmysterio   (29.05.14 02:52)
В основном объяснения идут в предыдущих уроках, но я могу детальнее остановится на Вашем вопросе на форуме. Код:
Код
1@ = 0 // Index Point      
9@ = 4 // Type Race Chackpoint      

:MISSION_C      
wait 0      
06D6: disable_racing_checkpoint 8@      
marker.Disable(10@)      
if      
1@ == 0      
then      
2@ = 2413.0439       
3@ = -1841.1782      
5@ = 2413.2087      
6@ = -2048.9414      
end      
// ...
if      
1@ == 9      
then      
2@ = 2582.5527       
3@ = -2116.0264       
5@ = 2583.7729       
6@ = -2082.8301       
9@ = 1 // Finish!      
end      
if      
1@ == 10      
then      
jump @MISSION_A      
end      
06D5: 8@ = create_racing_checkpoint_at 2@ 3@ 100.0 point_to 5@ 6@ 100.0 type 9@ radius 4.0      
018A: 10@ = create_checkpoint_at 2@ 3@ 50.0      

:MISSION_B      
wait 0      
if OR      
Car.Wrecked(0@)      
02BF: car 0@ sunk      
then      
jump @MISSION_29_144_END_CAR      
end      
if      
not actor.InCar($PLAYER_ACTOR, 0@)      
then      
jump @MISSION_29_144_PLAYER_NOT_CAR      
end      
if      
00EC: actor $PLAYER_ACTOR sphere 0 near_point 2@ 3@ radius 4.5 4.5      
then      
1@ += 1      
097A: at 0.0 0.0 0.0 play_sound 1056      
jump @MISSION_C      
end      
jump @MISSION_B

Переменная 1@ является счётчиком, то есть когда игрок находится на маркере, то прибавляется значение 1 к этой переменной. Это нужно для того, чтобы знать когда закончить миссию. В зависимости от значения 1@ маркеры создаются в последовательно в координатах 2@  и 3@. Переменные 5@ 6@ указывают координаты, куда будет направлен маркер(угол разворота так сказать). В цикле MISSION_B, идут основные проверки. Если игрок находится в точке 2@ 3@, то мы прибавляем к счётчику единицу, убираем маркер и прыгаем на метку MISSION_C, чтобы проверить - нужно ли создавать ещё очередной маркер или завершать миссию.

Magul-23   (10.10.14 10:23)
Собственно это даже не сюжетная миссия а скорее спортивная которую можно причислить к дисциплине лётной школы.
   Мой вопрос может показатся дятловатым однако многие нерешаются спросить а я спрошу: В main есть сюжетная миссия когда ГГ летит из вегаса к короне аж на Ч.Г. ,и оказывается в Либерти. Все помнят миссию в кафе святого Марка.
    Как выяснилось сама локация Либерти помещенна в интерьер. Я тоже делаю свою локацию в интерьере. И когда она будет готова её как то надо будет поместить в глобальный мод. Конечно можно просто CLEO скриптом создать маркер с переходом туда и обратно, но это бонально и очень скоро наскучит. А можно сделать началом глобального мода ------------MISSION 0------------ Где после кат сцены с гибелью офицера Темпени СJ  и Свита арестовывают и ссылают в зону отчуждения (локация где будет проходить первая половина всего сюжета глобального мода) Разумеется прохождение последующих миссий приближают геймера к возвращению в Лосс-Сантос. Но это наброски на будующее. В настоящем я ещё не умею писать в майне, да и в клео мои скрипты столь примитивны что даже не осмеливаюсь их выкладывать в поль зование...
  Ну так как? Можно ли подробно написать с исчерпывающими пояснениями код такой миссии. А уже адаптировать его под свой замысел постараюсь сам...

0
wmysterio   (10.10.14 18:40)
Если делать глобальный мод, то точно с новым main.scm. На клео-скриптах далеко не убежишь. Я лично использую Cleo-скрипты в основном для дебага мейна за искоючением нескольких модов от DK22Pack.
Цитата
Как выяснилось сама локация Либерти помещенна в интерьер.
Это само собой. Хочу отметить, если в интерьере сделать огромную локацию, то будет проблемма с её начелением, ведь в интерьерах не генерируются люди, транспорт и прочее. Нужно будет создавать отдельные скрипты для генерации этих сущностей а так же решать проблему с путями, иначе они будут ходить чёрт знает куда.

Magul-23   (12.10.14 11:09)
 
Цитата
если в интерьере сделать огромную локацию, то будет проблемма с её начелением, ведь в интерьерах не генерируются люди, транспорт и прочее. Нужно будет создавать отдельные скрипты для генерации этих сущностей а так же решать проблему с путями, иначе они будут ходить чёрт знает куда
Совершенно верно, твоя теория верна тем что на практике у меня уже были потуги оживить локацию в интерьере людьми и транспортом. Их перемещения были столь хаотичны что мне пришлось полностью деинсталировать весь пак скриптов которые тогда применил
Вход на сайт

Поиск
Категории раздела
Мини-чат
Пожалуйста, все вопросы по скриптингу задавать на форуме!
Наш опрос
Как Вы относитесь к ситуации с OpenIV?
Всего ответов: 9
Активность на сайте
Пожертвования
Кошельки WebMoney:
U859420971000
R407741810602
Z331072372430
E314272616890
Друзья сайта
Полезные ресурсы
Статистика

Онлайн всего: 1
Гостей: 1
Пользователей: 0

Сегодня нас посетили:
Рекомендую
Реклама